Устройство кода миссии
Ну что ж пришло время подробно рассмотреть устройство кода миссии.
Код миссии состоит из 4 блоков:
1. блок запуска
2. блок успешного прохождения
3. блок провала
4. блок завершения миссии
Блок запуска выглядит следующим образом:
:MISSION
thread 'MISSION'
gosub @MissionStart
if
wasted_or_busted
jf @MissionCleanup
gosub @MissionFailed
Командой thread 'MISSION' - даем имя нашему потоку, о полезности этого действия рассказывать не буду, это отдельная тема. Командой gosub @MissionStart мы и осуществляем переход к коду самой миссии, с последующим возвратом на следующую после gosub стоку.
Итак
gosub @MissionStart
. . . .
:MissionStart
< тело миссии>
return //– возвращаемся на следующую после gosub @MissionStart строку.
Сам return может быть как из блока успешного прохождения, так и из блока провала.
Блок успешного прохождения
Этот блок выполняется тогда, когда задание миссии выполнено.
Обычно в этом блоке выводится надпись об успешном прохождении миссии, увеличивают количество денег и т.д. Самый простой вариант выглядит так:
:MissionPassed
01E3: text_1number_styled 'M_PASSD' 0 5000 ms 1 // MISSION PASSED!
// выводим надпись об успешном прохождении миссии
0394: play_music 1 // проигрываем музыку
return // возвращаемся на следующую после gosub @MissionStart строку
Блок провала
Если же поставленное задание в миссии не выполнено, то в этом случае и применяется блок провала. А также этот блок выполняется в случае смерти или ареста игрока.
:MissionFailed
00BA: text_styled 'M_FAIL' 5000 ms 1 // ~r~MISSION FAILED!
// выводим надпись о провале миссии
create_thread @START
// запускаем стартер нашей миссии
return // возвращаемся на следующую после gosub @MissionStart строку
Для того чтобы после провала миссии иметь возможность еще раз пройти нашу миссию необходимо в блок провала включить create_thread @START – запуск стартера миссии, при условии, что стартер у нас рассчитан на запуск одной миссии. При последовательном запуске миссий этого делать не нужно.
Итак, мы выяснили, что при любом варианте (провал или успешное прохождение) все равно возвращаемся на следующую после gosub @MissionStart строку. Где собственно проверяется, убит или арестован игрок
gosub @MissionStart
if
wasted_or_busted // убит или арестован
jf @MissionCleanup // если нет, то переходим на блок завершения миссии
gosub @MissionFailed
// если убит или арестован, то переходим на блок провала с возвратом на
// следующую после gosub @MissionFailed строку
Блок завершения миссии
:MissionCleanup
$ONMISSION = 0 // integer values
mission_cleanup
end_thread
Этот блок необходим для корректного завершения миссии.
Команда mission_cleanup высвобождает память от всего созданного на протяжении миссии, уничтожаем всех актеров, машины и пр.
У нас уже есть рабочая заготовка миссии, но самой миссии, как таковой нет. Напишем простенькую миссию, суть которой успеть доехать до указанного места.
Для начала создаем автомобиль и поместим игрока около этого авто.
:MissionStart_27
wait 0
if
Model.Available(#BFINJECT)
jf @MissionStart_27
01EB: set_traffic_density_multiplier_to 0.0
// отключаем трафик
03DE: set_pedestrians_density_multiplier_to 0.0
// убираем появление случайных актеров
Player.CanMove($PLAYER_CHAR) = False
// делаем игрока неподвижным
02A3: toggle_widescreen 1 // включаем широкий экран
$car = Car.Create(#BFINJECT, 2636.431, -1730.885, 10.7281)
Car.Angle($car) = 89.3845
Actor.PutAt($PLAYER_ACTOR, 2634.789, -1722.628, 10.8984)
Actor.Angle($PLAYER_ACTOR) = 179.9178
04E4: unknown_refresh_game_renderer_at 2634.789 -1722.628
//делаем прорисовку местности в указанных координатах
Camera.SetAtPos(2634.789, -1722.628, 11.8984)
// и устанавливаем камеру
Camera.SetBehindPlayer
wait 500
fade 1 500
Поскольку это миссия, то нам необходимо объяснить играющему цель миссии, то есть, то что нужно сделать чтобы ее пройти. Для этого выводим текст на экран, а чтобы во время показа текста нам не мешали ни случайный транспорт ни актеры, мы и отключаем их появление. Нужные нам тексты находятся в разных GXT таблицах поэтому приходится для того чтобы текст отображался на экране загружать разные таблицы для каждого предложения.
:MissionStart_37
wait 0
054C: use_GXT_table 'GARAGE1'
//загружаем таблицу 'GARAGE1'
00BC: show_text_highpriority GXT 'GAR1_22' time 3000 flag 1
wait 3000
03D5: remove_text 'GAR1_22'
054C: use_GXT_table 'BLOOD'
00BC: show_text_highpriority GXT 'BLOD_01' time 5000 flag 1
wait 5000
03D5: remove_text 'BLOD_01'
00BC: show_text_highpriority GXT 'BLOD_02' time 5000 flag 1
wait 5000
03D5: remove_text 'BLOD_02'
Player.CanMove($PLAYER_CHAR) = True
// игроком можно управлять
02A3: toggle_widescreen 0 //отключаем широкий экран
Теперь, когда показ текста закончен нам необходимо проверить находится ли игрок в автомобиле, а затем уже создавать checkpoint и запускать таймер.
:MissionStart_39
wait 0
if
Actor.InCar($PLAYER_ACTOR, $car)
jf @MissionStart_39
Car.LockInCurrentPosition($car) = True
// Блокируем автомобиль
wait 2000
$TIME = 20000 //миллисекунды
//установим лимит времени в 20 секунд
03C3: set_timer_to $TIME type 1 GXT 'TIMER'
//будет обратный отсчет времни
06D5: $r_checkpoint = create_racing_checkpoint_at 2192.036 -1732.899 13.0168 point_to 0.0 0.0 0.0 type 1 radius 6.0
018A: $checkpoint = create_checkpoint_at 2192.036 -1732.899 13.0168
01EB: set_traffic_density_multiplier_to 1.0
03DE: set_pedestrians_density_multiplier_to 1.0
// включаем появление транспорта и пешеходов
Car.LockInCurrentPosition($car) = False
Итак таймер запущен, теперь необходимо проверить находится ли автомобиль в указанных координатах и не закончилось ли время.
:MissionStart_45
wait 0
if
$TIME > 0
jf @MissionFailed //если время истекло, то миссия провалена
if
0100: actor $PLAYER_ACTOR in_sphere 2192.036 -1732.899 13.0168 radius 6.0 6.0 6.0 sphere 0 in_car
jf @MissionStart_45
wait 50
Car.LockInCurrentPosition($car) = True
014F: stop_timer $TIME // останавливаем таймер
//удаляем модель, маркер, racing_checkpoint
06D6: disable_racing_checkpoint $r_checkpoint
Marker.Disable($checkpoint)
Model.Destroy(#BFINJECT)
Car.RemoveReferences($car)
//автомобиль переводим в разряд случайного транспорта
Car.LockInCurrentPosition($car) = False
jump @MissionPassed
:MissionPassed
01E3: show_text_1number_styled GXT 'M_PASSS' number 2000 time 5000 style 1
// MISSION PASSED!~n~~w~$~1~~n~~w~RESPECT +
0998: add_respect 3 // увеличим респект
Player.Money($PLAYER_CHAR) += 2000
// заплатим игроку за труды
0394: play_music 1
return
// возвращаемся на следующую после gosub @MissionStart строку
:MissionFailed
00BA: show_text_styled GXT 'M_FAIL' time 5000 style 1 // ~r~MISSION FAILED!
014F: stop_timer $TIME
// останавливаем таймер
//удаляем модель, маркер, racing_checkpoint
06D6: disable_racing_checkpoint $r_checkpoint
Marker.Disable($checkpoint)
Model.Destroy(#BFINJECT)
Car.RemoveReferences($car)
Car.LockInCurrentPosition($car) = False
create_thread @START
// запуск стартера миссии
return
// возвращаемся на следующую после gosub @MissionStart строку
Теперь у нас уже полноценная простенькая миссия, остается только скомпилировать файл и начать новую игру.
Vova
