Создаём меню (как при покупке одежды, оружия)
Создание меню (или Работа с таблицами).
В игре часто можно встретить появляющиеся таблицы с выбором каких-либо значений (еды, стрижки, оружия, татуировки, выбор веса снаряда в тренажерном зале и т.п.). Назвать их можно по разному: список, табло, меню и т.д, но в этой статье я буду их называть именно таблицами (позже вы поймете почему).
[Все строковые значения (записи в gxt-файле), использованые в примерах, я сразу заменил на конкретные значения на русском языке, для наглядности.]
Рассмотрим ее подробно:
Первый параметр 'ЗАГОЛОВОК ТАБЛИЦЫ' - это заголовок таблицы (то, что будет у написано нее на макушке большими буквами).
Далее идут координаты расположения верхней-левой точки таблицы на плоскости экрана (x и y). Начало координат в верхней-левой части экрана (0.0 0.0). Тип
дробный (float).
Следующий параметр [width] - Ширина одного столбца (именно одного столбца, а не всей таблицы). Число дробное. Высота не указывается, а определяется автоматически, в зависимости от количества строк.
Пятый параметр показывает, сколько столбцов будет у нашей таблицы. У меня получилось сделать максимум 4 столбца, но я думаю этого количества хватит для решения большинства задач. Чаще всего используется 1-2 столбца (например, название - цена).
Шестой параметр определяет, можно ли будет перемещать по таблице указатель, или указателя не будет вообще, в случае, если таблица используется только для показа какой-либо информации. 1 - с указателем, 0 - без.
Следующий параметр устанавливаетснимает фон. При значении 0, таблица будет без заднего фона (тоесть она будет прозрачной), а при еденице - с фоном.
Восьмой параметр влияет на выравнивание текста в таблице. 1 - по левому краю, 2 - по правому, 0 - посередине.
Ну и наконец, последний, но не менее важный параметр, идентификатор таблицы (тоесть имя переменной в памяти). Требуется для последующей работы с таблицей, например, для закрытия.
Команда которую мы рассмотрели выше лишь создает пустую таблицу с заголовком, но для ее заполнения существует другая команда:
___________________________
08DB: $mytable 0 'ЗАГОЛОВОК_СТОЛБЦА' 'СТРОКА0' 'СТРОКА1' 'СТРОКА2' 'СТРОКА3' 'СТРОКА4' 'СТРОКА5' 'СТРОКА6' 'СТРОКА7' 'СТРОКА8' 'СТРОКА9' 'СТРОКА10' 'СТРОКА11'
___________________________
Эта команда заполняет первый столбец записями. Если столбцов несколько, то эту команду необходимо повторять для каждого из них.
$mytable - идентификатор таблицы. 0 - номер заполняемого столбца.
Далее идут 13 текстовых параметров, первый из которых - заголовок столбца (имеет другой цвет, нежели последующие строки и его нельзя выделить курсором),
остальные 12 - значения каждой строки. Как видите, таблица ограничивается 12 строками.
ПРИМЕЧАНИЕ! Столбцы и строки нумеруются с нуля. Так что если в таблице два столбца, то номера у них будут 0 и 1. Точно также и со строками.
ВАЖНО! Даже если в вашей таблице всего три строки, прописать нужно всеравно все 13 (если считать загловок столбца), но только для пустых записей ставить
значение 'DUMMY'. Часто этим значением помечают и заголовок столбца, тем самым скрывая его:
___________________________
08DB: $mytable 0 'DUMMY' 'СТРОКА0' 'СТРОКА1' 'СТРОКА2' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY'
___________________________
Что же у нас получится в этом случае:
Для вывода числового значения в таблице используется команда:
___________________________
0006: @1 = 310 ;; integer values
08EE: $mytable 1 0 'DOLLAR' @1
___________________________
где $mytable - таблица
1 - номер столбца (можно подставить переменную в место конкретной цифры)
0 - номер строки (тоже можно подставить переменную)
'DOLLAR' - маска вывода. Принцип тот же самый что и при обычном выводе текста. (В данном случае = "$~1~"). То есть на экран выведется: $310
@1 - переменная, содержащая числовое значение (В данном случае 310)
Если таблицу мы используем в качестве меню (как это делается например, при покупке), то нам потребуется получить параметр, указывающий на выбранную игроком строку, а делается это командой:
___________________________
08D7: $mytable $number
___________________________
где $mytable - таблица,
$number - переменная в которую передается номер текущей записи (на которой стоит указатель). Именно по ней мы и определим, какой пункт выбрал игрок.
Убирается таблица с экрана следующей командой:
___________________________
08DA: $mytable
___________________________
Выравнивание текста для определенного столбца:
___________________________
08D6: $mytable 1 2
___________________________
$mytable - таблица
1 - номер столбца (еще раз напомню, начиная с нуля)
2 - выравнивание текста (1 - по левому краю, 2 - по правому, 0 - посередине)
Также для конкретного столбца можно указать и ширину:
___________________________
09DB: $mytable 0 280
___________________________
$mytable - таблица
0 - номер столбца
280 - ширина
Следующая команда ставит указатель на определенную строку:
___________________________
090E: $mytable 3
___________________________
Тут все просто: $mytable - таблица, 3 - номер строки.
Есть еще и другие команды, использующиеся для работы с таблицами, но основные команды, необходимые для работы с ними, я описал.
Да, и не забывайте замораживать игрока перед показом таблицы, чтоб он не бегал, когда вы будете переходить по записям:
01B4: set_player $PLAYER_CHAR frozen_state 0 (frozen), ну и соответственно потом разморозить.
Напоследок, проверенный пример:
Нажимаем на клавишу действия (Tab), появляется меню со списком причесок и цен. Для выбора нажать клавишу бега (у меня Shift, возможно у вас другая). Стричся конечно персонаж не будет, но какой пункт был выбран мы увидим на экране.
:TABLE_1
0001: wait 250 ms
00D6: if 1
0256: player $PLAYER_CHAR defined
00E1: key_pressed 0 4
004D: jump_if_false JJTABLE_1
01B4: set_player $PLAYER_CHAR frozen_state 0 (frozen) ;; Замораживаем игрока
08D4: 'HAIRCHO' 29.0 165.0 93.0 2 1 1 1 $mytable ;; Выводим таблицу
08D6: $mytable 0 1 ;; Задаем выравнивание для первого столбца по левому краю
09DB: $mytable 0 200 ;; Задаем ширину первого столбца, чтобы влезли надписи
08DB: $mytable 0 'HAIRSTY' 'TASH' 'GOATEE' 'BEARD' 'AFROT' 'AFROGOT' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY' ;; Заполняем первый столбец
;; Как видите я здесь использовал 'DUMMY' для остальных строк
08D6: $mytable 1 2 ;; Задаем выравнивание для второго столбца по правому краю
08DB: $mytable 1 'COST' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY' 'DUMMY' ;; Заполняем второй стобец
;; Ну на самом деле заполним мы его ниже, а пока выведем его с пустыми строками
0004: $price1 = 100 ;; Назначаем цены для причесок
0004: $price2 = 200
0004: $price3 = 300
0004: $price4 = 400
0004: $price5 = 500
08EE: $mytable 1 0 'DOLLAR' $price1 ;; Выводим цены в таблице
08EE: $mytable 1 1 'DOLLAR' $price2
08EE: $mytable 1 2 'DOLLAR' $price3
08EE: $mytable 1 3 'DOLLAR' $price4
08EE: $mytable 1 4 'DOLLAR' $price5
:TABLE_2
0001: wait 250 ms
00D6: if 0
00E1: key_pressed 0 16
004D: jump_if_false JJTABLE_2
08D7: $mytable $vibrano ;; Определяем номер строки, которая была выделена на момент выбора
08DA: $mytable ;; Закрываем таблицу
01B4: set player $PLAYER_CHAR frozen state 1 (unfrozen) ;; Размораживаем игрока
04F7: status_text $vibrano 0 line 3 "TEXT" ;; Выводи номер выбранной строки на экран
0001: wait 2000 ms
0151: remove_status_text $vibrano
0002: jump JJTABLE_1
Ну вот собственно и все. Используя эту информацию, можно строить собственные менюшки, таблицы, списки и т.д. Все ограничивается лишь вашей фантазией и 12-ю строками в таблице (хотя это не проблема, можно же вывести несколько таблиц, поочередно). У меня например, появилась идея насчет спидометра. Ведь скорость
необязательно выводить как status_text, можно вывести и в табличке, только не замораживать игрока.
Если будут вопросы, задавайте на форуме или в комментариях.
______
11.10.2005
Автор: Polter
Статья написана специально для сайта Missions.GTAMaps.net, публикация на других сайтах разрешена только с указанием источника и с соблюдением авторских прав.
974 Прочтений • [Создаём меню (как при покупке одежды, оружия)] [13.05.2012] [Комментариев: 0]
Vova
